SUBROUTINE drxiom(TR,RS,VS,OG11,OG22,OBX,OCX,OEX,ERROR) 
C**  Collision integrals using LJ for TR<10 and BM for TR>10  ** 
C**  coefs. from Bzowski et al. JPCRD v19 p1179 (1990).       ** 
C**  Range for 0.2<TR<1.0 has been fit to tables from         ** 
C**  Mason et al. with f, f' and f'' continuous at TR=1.      ** 
C                                                             ** 
C                  SNL / PHPaul  all rights reserved 1997     ** 
C                  last modified Sept/6/97                    ** 
C*************************************************************** 
C inputs: 
C  TR = reduced temperature 
C  RS = reduced Born-Mayer radius 
C  VS = reduced Born-Mayer energy 
C returns: 
C  ERROR = .FALSE. for normal end 
C        = .TRUE. for TR < 0.2 user should treat as fatal 
C  OG11 = normalized collision integral, type (1,1) 
C  OG22 = normalized collision integral. type (2,2) 
C  OEX = higher collision integral functional Estar 
C  OCX = higher collision integral functional Cstar 
C  OBX = higher collision integral functional Bstar 
C*************************************************************** 
      IMPLICIT NONE
#include "defs.h"

      LOGICAL ERROR 
      real*8 BT(4),G1(3),G2(3),G3(3),G(5),GL(6) 
      real*8 DT(5),F1(3),F2(3),F3(3),F(5),FL(6)

      double precision tr, at, og11, og22, a10, vs 
      double precision aa, gn01, gn02, gn03, b1, b2, b3 
      double precision sum1, rs, sum2, fn01, fn02, fn03 
      double precision obx, ocx, oex


      DATA BT /0.89D0,-267.0D0,26700.0D0,-8.9D5/ 
      DATA G1 /201.570D0,174.672D0,7.36916D0/ 
      DATA G2 /19.2265D0,27.6938D0,3.29559D0/ 
      DATA G3 /6.31013D0,10.2266D0,2.33033D0/ 
      DATA G /0.295402D0,-0.510069D0,0.189395D0, 
     &         -0.045427D0,0.0037928D0/ 
      DATA GL /0.295402D0,-0.510069D0,0.189395D0, 
     &          0.484463D0,0.417806D0,0.122148D0/  
      DATA DT /1.04D0,0.0D0,-33.0838,101.571,-87.7036/ 
      DATA F1 /20.0862D0,72.1059D0,8.27648D0/ 
      DATA F2 /56.4472D0,286.393D0,17.7610D0/ 
      DATA F3 /46.3130D0,277.146D0,19.0573D0/ 
      DATA F /0.46641D0,-0.56991D0,0.19591D0, 
     &         -0.03879D0,0.00259D0/ 
      DATA FL /0.46641D0,-0.56991D0,0.19591D0, 
     &          0.747363D0,0.662153D0,0.188447D0/      
C 
      IF(TR.LT.0.2D0) THEN 
        ERROR = .TRUE. 
        ELSE 
          ERROR = .FALSE. 
          ENDIF 
C 0.2 <= TR < 1.0 
      IF (TR.LT.1.0D0) THEN        
        AT = DLOG(TR)        
C  type I         
        OG11 = DEXP(GL(1)+AT*(GL(2)+AT*(GL(3)+AT*(GL(4)+ 
     &               AT*(GL(5)+AT*GL(6)))))) 
#ifndef FIRST_ORDER_DRFM
        OCX = 1.D0 + ( GL(2)+AT*(2.D0*GL(3)+AT* 
     &     (3.D0*GL(4)+AT*(4.D0*GL(5)+AT*5.D0*GL(6)))))/3.D0 
        HP1=(2.D0*GL(3)+AT*(6.D0*GL(4)+ 
     &      AT*(12.D0*GL(5)+20.D0*AT*GL(6))))/3.D0 
        OBX = 4.D0*OCX-3.D0*(OCX*OCX) - HP1 
#endif
C  type II           
        OG22 = DEXP(FL(1)+AT*(FL(2)+AT*(FL(3)+AT*(FL(4)+ 
     &            AT*(FL(5)+AT*FL(6) ))))) 
#ifndef FIRST_ORDER_DRFM
        OEX = 1.D0 +( FL(2)+AT*(2.D0*FL(3)+AT* 
     &   (3.D0*FL(4)+AT*(4.D0*FL(5)+5.D0*AT*FL(6)))) )/4.D0           
#endif
        RETURN 
        ENDIF 
C 1 <= TR <= 10.0 
      IF (TR.LE.10.D0) THEN 
        AT = DLOG(TR) 
C  type I         
        OG11 = DEXP (G(1)+AT*(G(2)+AT*(G(3)+AT*(G(4)+AT*G(5))))) 
#ifndef FIRST_ORDER_DRFM
        OCX = 1.D0+(G(2)+AT*(2.D0*G(3)+ 
     &            AT*(3.D0*G(4)+AT*4.D0*G(5))) )/3.D0 
        HP1=(2.D0*G(3)+AT*(6.D0*G(4)+AT*12.D0*G(5)))/3.D0 
        OBX = 4.D0*OCX-3.D0*(OCX*OCX) - HP1  
#endif
C  type II         
        OG22 = DEXP (F(1)+AT*(F(2)+AT*(F(3)+AT*(F(4)+AT*F(5) )))) 
#ifndef FIRST_ORDER_DRFM
        OEX = 1.D0 + ( F(2)+AT*(2.D0*F(3)+AT* 
     &           (3.D0*F(4)+AT*4.D0*F(5))) )/4.D0              
#endif
        RETURN 
        ENDIF 
C TR > 10.0     
      A10 = DLOG(0.1D0*VS) 
      AA = DLOG(VS/TR) 
C  type I         
      AT = 1.D0/(TR*TR) 
      gn01 = g1(3)/a10
      gn02 = g2(3)/a10
      gn03 = g3(3)/a10
      B1 = G1(1)+G1(2)/A10+gn01*gn01
      B2 = (G2(1)+G2(2)/A10+gn02*gn02)*(-1.D3) 
      B3 = (G3(1)+G3(2)/A10+gn03*gn03)*(1.D5) 
      SUM1 = RS*RS*(BT(1)+AT*(BT(2)+AT*(BT(3)+AT*BT(4)))) 
      SUM2 = AT*(B1+AT*(B2+AT*B3))/(A10*A10) 
      OG11 = (SUM1 + SUM2) * (AA*AA) 
#ifndef FIRST_ORDER_DRFM
      SUM3 = RS*RS*AT*(BT(2)+AT*(2.D0*BT(3)+3.D0*AT*BT(4))) 
      SUM4=AT*(B1+AT*(2.D0*B2+AT*3.D0*B3))/(A10*A10) 
      HP1 = (SUM3+SUM4)/(SUM1+SUM2) 
      OCX = 1.D0-((1.D0/AA)+ HP1 )*2.D0/3.D0 
      SUM5=RS*RS*AT*(2.D0*BT(2)+AT*(8.D0*BT(3)+18.D0*AT*BT(4))) 
      SUM6=AT*(2.D0*B1+AT*(8.D0*B2+AT*18.D0*B3))/(A10*A10) 
      HP2 = (SUM5+SUM6)/(SUM1+SUM2) +2.D0*(HP1*HP1) 
      OBX = 4.D0*OCX-3.D0*(OCX*OCX)+((1.D0/(AA*AA))-HP2)*2.D0/3.D0  
#endif
C  type II         
      AT = 1.D0/DLOG(TR) 
      fn01 = f1(3)/a10
      fn02 = f2(3)/a10
      fn03 = f3(3)/a10
      B1 = F1(1)+F1(2)/A10+fn01*fn01
      B2 = (F2(1)+F2(2)/A10+fn02*fn02)*(-1.D0) 
      B3 = (F3(1)+F3(2)/A10+fn03*fn03) 
      SUM1=RS*RS*(DT(1)+AT*AT*(DT(3)+AT*(DT(4)+AT*DT(5)))) 
      SUM2 = AT*AT*(B1+AT*(B2+AT*B3))/(A10*A10) 
      OG22 = (SUM1 + SUM2) * (AA*AA) 
#ifndef FIRST_ORDER_DRFM
      SUM3 = RS*RS*AT*AT*AT*(2.D0*DT(3)+AT*(3.D0*DT(4)+ 
     &          4.D0*AT*DT(5))) 
      SUM4 = AT*AT*AT*(2.D0*B1+AT*(3.D0*B2+AT*4.D0*B3))/(A10*A10) 
      OEX = 1.D0-( 2.D0/AA + (SUM3+SUM4)/(SUM1+SUM2) )/4.D0         
#endif
      RETURN  
      END